2011年1月21日 星期五

NxN列聯表計算卡方檢定修改版2.1

本文僅進行前一版本NxN列聯表計算卡方檢定,做內部預設值之設定,不影響前一版本執行結果。

目前僅能執行獨立性卡方檢定及Fisher's exact檢定,
並且關閉一些結果表的顯示,如要呈現其他項目 如表格內百分比,
請於執行前在程式尾端自行修改


DM LOG 'CLEAR';
DM OUTPUT 'CLEAR';

Data Welcom;
Window Welcom Color=white Columns=100 Rows=100
#5 @50 "-------------歡迎使用本SAS程式Window視窗版--------------" color=red
#7 @50 "----------此程式使用於卡方檢定(樣本獨立性檢定)----------" color=red
#9 @50 "------------------------列聯表分析----------------------" color=blue
#14 @50 "請按Enter進入欄位設定及檢定視窗"

#18 @50 "註:本分析程式僅呈現列聯表及進行卡方統計處理,如要顯示其他數據如期望值、百分比等," color=blue
#19 @50 " 請執行前自行於本程式最末端修改,尚不包含適合度檢定其他分佈期望值" color=blue
;
Display Welcom ;
stop ;
run;

%let x=2;
%let y=2;
Data SelectTable;
retain x 2 y 2;
Window Select Color=white Columns=100 Rows=100

#1 @58 '--------------列聯表分析--------------' color=red
#3 @58 '請輸入為X乘Y列聯表' color=red
#5 @52 'X*Y=' color=blue
#5 @63 '*' color=red
#5 @58 x 5. color=red a=underline auto=yes required=yes
#5 @64 y 5. color=red a=underline auto=yes required=yes


#13 @50 "本列聯表預設值為2X2,如欲使用其他列聯,請將數值刪除再改為自己需要的"
#14 @50 "並在各欄位數值鍵入完或最右下欄位鍵入完,請按鍵盤Enter鍵,以方便跳位及資料進入SAS程式內"
#15 @50 "當各數值鍵入完成後請至上方Command===>處鍵入關鍵字: end"

;
Display Select ;

run;

proc sql ;
select x , y into :x ,:y
from SelectTable (obs=1);
run;
quit;


%macro Tabletrans;


Data Tablewindow;

retain
%do ssy= 1 %to &y;
%do ssx = 1 %to &x ;
x&ssx.y&ssy 0
%end;
%end;
;

Window Table Color=white Columns=100 Rows=100

#3 @58 '變相X' color=red


%do xn=1 %to &x;
%let xsit=%eval(43+10*&xn);
#4 @&xsit "X=&xn" color=blue
%end;

#7 @43 '變' color=red
#8 @43 '項' color=red
#9 @43 'Y' color=red

%do yn=1 %to &y;
%let ysit=%eval(4+3*&yn);
#&ysit @46 "Y=&yn" color=blue
%end;

%let vlbar=%eval(5+3*&y);
%let xbar="----------" ;
#5 @50
%do b=1 %to &x ;
&xbar
%end;

%let xbar="----------" ;
#&vlbar @50
%do b=1 %to &x ;
&xbar
%end;

%do vb=1 %to &y;
%let vspec=%eval(5+3*(&vb-1));
%Let xcbar='|---------' ;
#&vspec @50
%do b=1 %to &x ;
&xcbar
%end;
%end;

%do a= 1 %to &y ;
%let vca1=%eval(6+3*(&a-1));
%let vca2=%eval(7+3*(&a-1));
%let vca3=%eval(8+3*(&a-1));
%let h=%eval(&x+1);
%do hbarn= 1 %to &h ;
%let hbar=%eval(40+10*&hbarn) ;
#&vca1 @&hbar '|'
#&vca2 @&hbar '|'
%end;
#&vca3 @&hbar '|'
%end;

%do yyy= 1 %to &y;
%let varys=%eval(3+3*&yyy);

%do xxx = 1 %to &x ;
%let varxspe=%eval(41+10*&xxx);


#&varys @&varxspe x&xxx.y&yyy 5. color=red a=underline auto=yes required=yes

%end;

%end;

%let footnote1=%eval(&vlbar+5);
%let footnote2=%eval(&vlbar+6);
#&footnote1 @50 "請將預設值先行刪除,並在各欄位數值鍵入完或最右下欄位,按Enter以方便跳位"
#&footnote2 @50 "鍵入完成後請至上方Command===>處鍵入 : end"
;
Display Table;
run;

%mend;
%Tabletrans;
proc transpose data=Tablewindow prefix=weight name=local out=weightnum;
run;


data tablecut;
set weightnum;
xx=scan(local,1 , 'y');
xxx=scan(xx,1,'x');
yyy=scan(local,2 , 'y');
label xxx='變項X' yyy='變項Y';
run;




proc freq data= tablecut;
table yyy*xxx /chisq norow nocol nopercent exact;
weight weight1;
run;





2010年11月11日 星期四

proc corr

Crobanch's-alpha 的計算

Crobanch's-alpha 的計算

Crobanch's-alpha 的計算
之前寫給人的計算過程
在sas proc corr 計算中 的alpha功能 所求得之結果相同

2010年4月9日 星期五

建立外部資料庫連線-以MS資料庫為例

此例簡單敘述如何將外部或遠端資料庫如MS SQL 等的資料與SAS做連線

在此不多詳述MS SQL的資料建立

此例以MS SQL SERVER為例

若要與SAS做連線則要先有ODBC 或 OLAP 等設定

首先需建立ODBC連線設定
設定方式
>控制台>系統管理工具>資料來源(ODBC)
如下圖


選擇使用者資料來源名稱
新增SQL Server
如下圖


之後會有建立SQL SERVER 來源

視窗名稱就是你自己命名
連線伺服器就是要連線的ip位址或網路芳鄰
若是在本機上則打local或localhost即可
接著就會有連線帳號的設定與授權(需要在SQL SERVER先設定連線帳號)
上述即為MS SQL SERVER連線的設定前驅作業
此ODBC設定完成即可以在其他程式都能連線例如ACCESS、SPSS、SAS EG、SAS、ArcGIS.....等
只要能支援外部資料庫連線均能使用

接下來則是要使用SAS主程式
連線此MS SQL SERVER資料庫
首先先開啟SAS主程式
開啟左側Libraries資料夾


對著Explorer窗格按滑鼠右鍵或上方新增一個新的libraries



選擇Engine=>ODBC
Name則是你要新建立Libraries的名稱
若開啟ODBC則會有其他選項
如DataSource則是問你MS SQL SERVER允許你連線的資料庫有哪幾樣
你要選哪一個

如果成功就能開啟連線狀態


再來要怎麼使用因該就不用我多說了吧,暫存檔work和永久檔的使用。

上述SAS的設定可以利用libname語法去設定
只是用點選會比較快且只是一次性的設定
若資料庫較隱密時帳號密碼也比較不會曝光

2010年2月1日 星期一

NxN列聯表計算卡方檢定

繼之前簡易2X2列聯表計算卡方檢定只能計算2X2之列聯表
windows都升級為Win7了
當然列聯表也得升級一下
所以我改寫了新版wondow視窗
擴充為NxN列聯表
程式如下
直接在SAS內執行即可
Data Welcom;
Window Welcom Color=white Columns=100 Rows=100
#5 @50 "--------------Welcom To Use this SAS Program--------------" color=red
#7 @50 "------------This Program Test For Independence------------" color=red
#9 @50 "----------------Contingency Table Analysis----------------" color=blue
#14 @50 "請按Enter進入欄位設定及檢定視窗"
;
Display Welcom ;
stop ;
run;
Data SelectTable;
retain x 2 y 2;
Window Select Color=white Columns=100 Rows=100

#1 @58 '--------------Contingency Table Analysis--------------' color=red
#3 @58 '請輸入為X乘Y列聯表' color=red
#5 @52 'X*Y=' color=blue
#5 @63 '*' color=red
#5 @58 x 5. color=red a=underline auto=yes required=yes
#5 @64 y 5. color=red a=underline auto=yes required=yes



#14 @50 "各欄位數值鍵入完請按Enter以方便跳位"
#15 @50 "鍵入完成後請至上方Command===>處鍵入 : end"

;
Display Select;

run;

proc sql ;
select x , y into :x ,:y
from SelectTable (obs=1);
run;
quit;


%macro Tabletrans;


Data Tablewindow;

retain
%do ssy= 1 %to &y;
%do ssx = 1 %to &x ;
x&ssx.y&ssy 0
%end;
%end;
;

Window Table Color=white Columns=100 Rows=100

#3 @58 '變相X' color=red


%do xn=1 %to &x;
%let xsit=%eval(43+10*&xn);
#4 @&xsit "X=&xn" color=blue
%end;

#7 @43 '變' color=red
#8 @43 '項' color=red
#9 @43 'Y' color=red

%do yn=1 %to &y;
%let ysit=%eval(4+3*&yn);
#&ysit @46 "Y=&yn" color=blue
%end;

%let vlbar=%eval(5+3*&y);
%let xbar="----------" ;
#5 @50
%do b=1 %to &x ;
&xbar
%end;

%let xbar="----------" ;
#&vlbar @50
%do b=1 %to &x ;
&xbar
%end;

%do vb=1 %to &y;
%let vspec=%eval(5+3*(&vb-1));
%Let xcbar='|---------' ;
#&vspec @50
%do b=1 %to &x ;
&xcbar
%end;
%end;

%do a= 1 %to &y ;
%let vca1=%eval(6+3*(&a-1));
%let vca2=%eval(7+3*(&a-1));
%let vca3=%eval(8+3*(&a-1));
%let h=%eval(&x+1);
%do hbarn= 1 %to &h ;
%let hbar=%eval(40+10*&hbarn) ;
#&vca1 @&hbar '|'
#&vca2 @&hbar '|'
%end;
#&vca3 @&hbar '|'
%end;

%do yyy= 1 %to &y;
%let varys=%eval(3+3*&yyy);

%do xxx = 1 %to &x ;
%let varxspe=%eval(41+10*&xxx);


#&varys @&varxspe x&xxx.y&yyy 5. color=red a=underline auto=yes required=yes

%end;

%end;

%let footnote1=%eval(&vlbar+5);
%let footnote2=%eval(&vlbar+6);
#&footnote1 @50 "各欄位數值鍵入完請按Enter以方便跳位"
#&footnote2 @50 "鍵入完成後請至上方Command===>處鍵入 : end"
;
Display Table;
run;

%mend;
%Tabletrans;
proc transpose data=Tablewindow prefix=weight name=local out=weightnum;
run;


data tablecut;
set weightnum;
xx=scan(local,1 , 'y');
xxx=scan(xx,1,'x');
yyy=scan(local,2 , 'y');
label xxx='變項X' yyy='變項Y';
run;




proc freq data= tablecut;
table yyy*xxx /chisq norow nocol nopercent;
weight weight1;
run;







不過最大值好像18*18 就很緊繃了
因為會超出視窗..............

2010年1月22日 星期五

實驗組與對照組一對一或一對多簡單配對

以下只是簡單介紹如何使用SAS語法做出實驗組與對照組在配對樣本時的簡單方法


一對一配對資料

先準備實驗組與對照組資料

data case;
input id name$ sex age BMI;
cards;
1 a 1 20 20
2 b 1 21 20
3 c 1 22 21
4 d 1 23 21
5 e 1 24 22
6 f 2 25 22
7 g 2 26 23
8 h 2 27 23
9 i 2 28 24
10 j 2 29 24
;
run;
data control;
input id name$ sex age BMI;
cards;
1 c1 2 29 24
2 c2 2 28 24
3 c3 2 27 20
4 c4 2 26 20
5 c5 2 25 21
6 c6 1 20 22
7 c7 1 21 21
8 c8 1 22 22
9 c9 1 23 23
10 c10 1 24 23
;
run;


若想要做到配對,其配對條件為性別配對
則每一筆皆有可能被對應到的結果如下


若為年齡或其他條件配對,其結果也是相似的。

case組每一筆觀察值皆對應到control組符合條件的觀察值
而要從中隨機抽出control組其中一筆作為case組配對結果,即作為一對一簡單配對的動作

其方法則要借用到SQL的模糊比對
在SAS中有類似TSQL語法的 PROC SQL程序
其步驟如下


data case;
input id name$ sex age BMI;
cards;
1 a 1 20 20
2 b 1 21 20
3 c 1 22 21
4 d 1 23 21
5 e 1 24 22
6 f 2 25 22
7 g 2 26 23
8 h 2 27 23
9 i 2 28 24
10 j 2 29 24
;
run;

data control;
input id name$ sex age BMI;
randseed=uniform(0);
cards;
1 c1 2 29 24
2 c2 2 28 24
3 c3 2 27 20
4 c4 2 26 20
5 c5 2 25 21
6 c6 1 20 22
7 c7 1 21 21
8 c8 1 22 22
9 c9 1 23 23
10 c10 1 24 23
;
run;

上述語法中先給Control組每個觀察值一個隨機號碼即亂數randseed,其值0~1。
亂數子的用法uniform(seed)
其實是執行一組符合均值分布的亂數產生器(the Uniform Random Number Generator)
seed則是亂數用到的亂數子可以隨意給定,其值為0到2^31-1之間

另有其他分布的亂數產生器可以用,如Ranbin(seed,n,p)、Rancau(seed)等
可參考如下


本次所要做的則是給定每個觀察值機會均等,所以使用uniform(0),seed則給0。

在給予亂數後
每個觀察值就有亂數之變項randseed可以取用,接下來則是透過配對結果如先前說到,每個Case組有不止一筆Control資料,取每一組Case組配對的Control組其亂數最小作為Case組配對一次的對象。

在給予每筆觀察值後
首先先利用SQL語法達到配對效果
語法如下

data case;
input id name$ sex age BMI;
randseed=uniform(0);
cards;
1 a 1 20 20
2 b 1 21 20
3 c 1 22 21
4 d 1 23 21
5 e 1 24 22
6 f 2 25 22
7 g 2 26 23
8 h 2 27 23
9 i 2 28 24
10 j 2 29 24
;
run;

data control;
input id name$ sex age BMI;
randseed=uniform(0);
cards;
1 c1 2 29 24
2 c2 2 28 24
3 c3 2 27 20
4 c4 2 26 20
5 c5 2 25 21
6 c6 1 20 22
7 c7 1 21 21
8 c8 1 22 22
9 c9 1 23 23
10 c10 1 24 23
;
run;


proc sql;
create table match as
select
case.id as case_id ,
case.name as case_name ,
case.sex as case_sex ,
case.age as case_age ,
case.BMI as case_BMI ,
case.randseed as case_randseed ,
control.id as control_id ,
control.name as control_name ,
control.sex as control_sex ,
control.age as control_age ,
control.BMI as control_BMI ,
control.randseed as control_randseed
from case , control
where case.sex = control.sex;
run;
quit;


上述SQL語法模糊配對的方式在於where case.sex = control.sex;
其實只是告知電腦你要找Case組與Control組條件在於性別相等時成立的結果
即口語上的哪裡是(where)Case組sex等於Control組sex的結果。
若有其他配對條件時也是在這裡執行,如要配對性別及年齡時,可以改為
where case.sex = control.sex and case.age = control.age


SQL檢索完成後之資料轉存到WORK資料夾的MATCH檔。
其結果如下圖(與前述提到每一筆Case組對應到Control組時的狀態)



完成條件檢索後需要進一步篩選每筆Case組只要一筆Control組,達到一對一配對,
其簡單方式則是把Case組取為原觀察數並且選擇Case組亂數最小或最大的保留
即一比一簡單配對方式
方式如下

proc sort data=match; by case_id control_randseed;
data One_TO_One;
set match ; by case_id ;
firstid=first.case_id;
lastid=last.case_id;
if firstid=1 and (lastid=0 or lastid=1) ;
run;

上述語法則是利用系統內設值first last,
若要了解SAS內設語法請自行查詢SAS的Help檔。
其用法是將Case組每一筆觀察值在SQL檢索後產生的重複資料整理為原來的筆數,並且保留了Control組亂數最小的那一筆。
若要一對二配對 另有比較偷懶的方式,就是重複資料取第一筆與最後一筆。



整體結果就是一對一的簡單配對






若要做其他配對方式只要照幾個原則便容易很多
1.觀察值先建立亂數
2.利用SQL語法中where的條件指令做模糊比對
3.根據需求如何取回現有的觀察值及觀察值的配對數目


上述除了能做群體配對與個體配對外
若只想從對照組隨機抽取
可以嘗試使用 PROC SURVEYSELECT 語法

2009年5月22日 星期五

window

簡易2X2列聯表卡方檢定


NxN列聯表計算卡方檢定


NxN列聯表計算卡方檢定修改版2.1

簡易2X2列聯表卡方檢定

簡易2X2列聯表計算卡方檢定

以下純屬為了方便計算2X2列聯所產生的簡易視窗版輸入,直接執行以下語法就能產生2X2列聯表
僅供方便將次數後的結果做2X2的卡方檢定,且視窗仍在改良中,趣味趣味玩玩就好。


Data Tablewindow;
retain x1 0 x2 0 x3 0 x4 0;
window Table Color=white Columns=100 Rows=100
#3 @58 '變相X' color=red
#4 @53 'X=1' color=blue
#4 @63 'X=2' color=blue
#7 @44 '變' color=red
#8 @44 '項' color=red
#9 @44 'Y' color=red
#7 @47 'Y=1' color=blue
#9 @47 'Y=2' color=blue

#5 @50 '---------------------'
#6 @50 '|' #6 @60 '|' #6 @70 '|'
#7 @50 '|' #7 @60 '|' #7 @70 '|'
#8 @50 '|---------' #8 @60 '|---------' #8 @70 '|'
#9 @50 '|' #9 @60 '|' #9 @70 '|'
#10 @50 '|' #10 @60 '|' #10 @70 '|'
#11 @50 '---------------------'

#6 @51 x1 5. color=red a=underline auto=yes required=yes
#6 @61 x2 5. color=red a=underline auto=yes required=yes

#9 @51 x3 5. color=red a=underline auto=yes required=yes
#9 @61 x4 5. color=red a=underline auto=yes required=yes

#14 @50 "各欄位數值鍵入完請按Enter以方便跳位"
#15 @50 "鍵入完成後請至上方Command===>處鍵入 : end"

;
Display Table;
run;

proc transpose data=Tablewindow prefix=weight name=local out=weightnum;
run;
data tablelocal;
input x y local$;
cards;
1 1 x1
2 1 x2
1 2 x3
2 2 x4
;
run;
data tablecom;
update tablelocal weightnum; by local;
run;

proc freq ;
label x="變項一" y="變項二";
table y*x /chisq norow nocol nopercent;
weight weight1;
run;

2009年3月5日 星期四

proc sql

An Introduction to SAS PROC SQL

實驗組與對照組一對一或一對多簡單配對

An Introduction to SAS PROC SQL

原文出處:http://www2.sas.com/proceedings/sugi27/p070-27.pdf

此文為SAS PROC SQL的簡單介紹 可以當作入門學習的文章


1.Creating output and new tables
2.Duplicates and sorting
3.Sub-setting and Caculating
4.Joining Tables
5.Proc SQL and SAS Macro language
6.Editing Observations
7.Data Table Management


1.Creating output and new tables

當我們要對某資料做搜尋時甚至做處理的動作可利用SQL語法來達到
以下為資料king做SQL的選取
其中沒有針對特定變項時的作法如下

data king;
input OBS PATIENT DATE date7. PULSE TEMP BPS BPD ;
cards;
1 101 25MAY01 72 98.5 130 88
2 101 01JUN01 75 98.6 133 92
3 101 08JUN01 74 98.5 136 90
4 102 30JUL01 81 99.0 141 93
5 102 06AUG01 77 98.7 144 97
6 102 13AUG01 78 98.7 142 93
7 103 24JUL01 77 98.3 137 79
8 103 31JUL01 77 98.5 133 74
9 103 07AUG01 78 98.6 140 80
10 103 14AUG01 75 99.2 147 89
11 104 22AUG01 72 98.8 128 83
12 104 29AUG01 69 99.1 131 86
13 104 05SEP01 71 98.9 127 82
;
run;

PROC SQL;
SELECT *
FROM king;
QUIT;



SAS SQL語法是以
PROC SQL;開始
QUIT;做結束

資料搜尋如說故事一樣 先打上SELECT
並且選擇要找的變相,如上則是選擇所有變相所以以*號為標記
若要選擇特定變項時 只要列出各變相 並且以逗號做區隔
如SELECT PATIENT, DATE, BPS, BPD

接著要搜尋的原資料來源宣告為FROM king;
就能夠成簡單的SQL搜尋語法

並且注意SELECT到FROM 都沒有用到;號做結束
只有在FROM後面才做結束的動作

其SQL搜尋結果如下



此外上述的動作僅在秀出報表(類似proc print的動作)
若要把搜尋的結果以新的資料型態出現時可以改為
PROC SQL;
CREATE TABLE kingbee AS
SELECT PATIENT, DATE, BPS, BPD
FROM king;
QUIT;


其中 CREATE TABLE AS 為固定用語
SQL搜尋後將資料轉為kingbee檔
其結果如下


上述中若資料的變相多時會有搜尋上的麻煩
如100個變相要選取便要在SELECT那邊打上100個變相名稱
這在語法上會有累人的地方
故有keep drop語法可以供使用,只要在from那邊做宣告
其方法如下
PROC SQL;
CREATE TABLE kingbee AS
SELECT *
FROM king (DROP=TEMP);
QUIT;

其結果如下



2.Duplicates and sorting

當在使用SQL語法選取特定變項時有時會希望知道該特定變項由哪些數值所構成
這時可以在欲選取的變項前額外宣告 DISTINCT,語法如下


PROC SQL;
SELECT DISTINCT PATIENT
FROM king;
QUIT;


這時只會顯示PATIENT變項內所構成的數值有哪些,其結果如下




若對於選取資料欲做排序的動作可以加入order by,並且可
在選取變項後,針對特定變項使用descending(降冪)或ascending(升冪)來配合排序,語法如下

PROC SQL;
SELECT PATIENT, DATE
FROM king
ORDER BY PATIENT descending, DATE ;
QUIT;


其結果如下



3.Sub-setting and Caculating
當選取的變項欲作額外計算或是修改其屬性時
可以在選取時接在後方 或是 在後方 宣告
此外對於PATIENT選取時只選出其值為101、103的資料
其語法如下

PROC SQL;
CREATE TABLE kingbee AS
SELECT PATIENT, DATE FORMAT=DATE7., BPS,
BPD, (TEMP-32)/9*5 AS TEMPC
FROM king
WHERE PATIENT IN (101 103)
ORDER BY PATIENT, DATE DESCENDING;
QUIT;


其中 Date 格式轉為DATE7.

將(TEMP-32)/9*5計算而成為TEMPC變項,中間以as(顧名思義:如同為)做宣告

透過where的宣告將PATIENT變項中含101及103之觀察值列出
其語法中WHERE PATIENT IN (101 103),in 的用法可變化為
where PATIENT=101 or PATIENT=103;

其結果如下



倘若在格式上的設定也可以額外改寫不同表達方式
如原來的DATE FORMAT=DATE7,可以改用put來宣告
如PUT(DATE,DATE7.) AS CDATE LENGTH=7

其語法如下
PROC SQL;
CREATE TABLE kingbee AS
SELECT PATIENT, PUT(DATE,DATE7.) AS CDATE LENGTH=7, BPS,
BPD, (TEMP-32)/9*5 AS TEMPC
FROM king
WHERE PATIENT IN (101 103)
ORDER BY PATIENT, DATE DESCENDING;
QUIT;

其中 put(DATE,DATE7.) 是將DATE變相轉換為DATE7.的格式
而LENGTH=7則是宣告新的變項CDATE在轉換格式後的長度

其結果如下




另外對於SQL也可以做一些搜尋過程的計算
如求出資料有多少筆數、平均值、變更資料的進位問題.....等等諸如此類的
其語法如下

PROC SQL;
SELECT
COUNT(*) AS N,
ROUND(MEAN(BPS),0.01) FORMAT=6.2 AS BPSMEAN,
ROUND(MEAN(BPD),0.01) FORMAT=6.2 AS BPDMEAN
FROM king;
QUIT;


其中COUNT(*) AS N 則是求出觀察值有幾筆

ROUND(MEAN(BPS),0.01)是先以MEAN()函數求出BPS的平均值
再以ROUND()函數宣告該平均值以小數點兩位作四捨五入的進位

其結果如下



此外SQL的語法是具有彈性的
所以當有特別針對某變項中的特定值作額外計算時也可以利用where配合
如下

PROC SQL;
SELECT
COUNT(*) AS N,
ROUND(MEAN(BPS),1) FORMAT=6.2 AS BPSMEAN,
ROUND(MEAN(BPD),1) FORMAT=6.2 AS BPDMEAN
FROM king
WHERE PATIENT IN (101 103);
QUIT;

因為針對PATIENT的101及103的結果做選取
所以樣本數N則為7筆,並且平均值也跟著不同


而在SQL的語法中
若要針對群組(GROUP)分類時
可以利用GROUB by語法
如下

PROC SQL;
SELECT PATIENT,
COUNT(PATIENT) AS N,
DATE,
BPD,
MAX(BPD) AS BPDHIGH,
ROUND(BPD/(CALCULATED BPDHIGH)*100, 0.01) AS BPDPCT
FROM king
GROUP BY PATIENT
;
QUIT;

GORUP BY用法須與全域宣告語法作配合方能顯示出其實用性
如GROUP BY PATIENT是宣告針對四個族群101、102、103、104來探討後續計算的動作,而用途
如COUNT(PATIENT) AS N是用來計數觀察值,若有GROUP BY 做配合時
則只會計算依據PATIENT分類(101、102、103、104)中的觀察值

如MAX(BPD) AS BPDHIGH則是取BPD變相中最大值,若直接使用時僅會挑處整個資料的最大值97
若有GROUP BY 做配合時則只會計算依據PATIENT分類(101、102、103、104)中的觀察值選出各自的最大值(92、97、89、86)
而後續的計算BPDPCT則是引用到group by時各自挑出的最大值,所以必須以CALCULATED做BPDHIGH引用的宣告

其結果如下


而下列語法中另使用HAVING宣告其顧名思義就是在透過群族後保留特定意義的語法

PROC SQL;
SELECT PATIENT,
COUNT(PATIENT) AS N,
DATE,
BPD,
MAX(BPD) AS BPDHIGH,
ROUND(BPD/(CALCULATED BPDHIGH)*100, 0.01) AS BPDPCT
FROM king
GROUP BY PATIENT
HAVING BPD = CALCULATED BPDHIGH
;
QUIT;

其語法則是只保留BPD變相與挑選出最大值BPDHIGH變相相等之觀察值
其結果如下



若需要針對特定群族做修改或計算時
可透過CASE的宣告方式來完成
其用法很像IF THEN
其語法為

CASE 條件項或目標變項
WHERE 條件值1 THEN 結果值1
WHERE 條件值2 THEN 結果值2
....
ELSE 上述條件不符時的其餘結果值
END AS 處理後的變項名稱

其語法如下

PROC SQL;
SELECT PATIENT,
CASE PATIENT
WHEN 101 THEN 'A'
WHEN 102 THEN 'B'
WHEN 102 THEN 'B'
ELSE 'D'
END AS GP "群組"
FROM king
;
QUIT;


其結果如下






4.Joining Tables


如今有一個新資料想要併入原來的資料,有如DATA步驟時的MERGE語法
原資料與新資料如下

data king;
input OBS PATIENT DATE date7. PULSE TEMP BPS BPD ;
cards;
1 101 25MAY01 72 98.5 130 88
2 101 01JUN01 75 98.6 133 92
3 101 08JUN01 74 98.5 136 90
4 102 30JUL01 81 99.0 141 93
5 102 06AUG01 77 98.7 144 97
6 102 13AUG01 78 98.7 142 93
7 103 24JUL01 77 98.3 137 79
8 103 31JUL01 77 98.5 133 74
9 103 07AUG01 78 98.6 140 80
10 103 14AUG01 75 99.2 147 89
11 104 22AUG01 72 98.8 128 83
12 104 29AUG01 69 99.1 131 86
13 104 05SEP01 71 98.9 127 82
;
run;
data king2;
input OBS PATIENT DATE : date7. MED $ 5. DOSES AMT UNIT $ ;
cards ;
1 102 30JUL01 Med A 2 1.2 mg
2 102 06AUG01 Med A 3 1.0 mg
3 102 13AUG01 Med A 2 1.2 mg
4 103 24JUL01 Med B 3 3.5 mg
5 103 31JUL01 Med B 3 3.5 mg
6 103 08AUG01 Med B 3 3.5 mg
7 104 22AUG01 Med A 2 1.5 mg
8 104 29AUG01 Med A 2 1.5 mg
9 104 05SEP01 Med A 2 1.5 mg
10 105 18JUN01 Med B 1 4.5 mg
11 105 25JUN01 Med B 2 3.0 mg
12 105 02JUL01 Med B 1 5.0 mg
;
run;



其中欲將原資料king檔與king2檔作PATIENT與DATE變相的配對
則可以利用 join語法
其與法如下

PROC SQL;
SELECT

king.PATIENT, king.DATE AS DATE, king.PULSE ,

king2.MED, king2.DOSES, king2.AMT

FROM king inner JOIN king2
on (king.PATIENT = king2.PATIENT) and (king.DATE = king2.DATE)
;
QUIT;


此處語法因使用king與king2兩資料時則須在select使用變項時註明原資料檔名
而在合併時須打上
檔案1 inner join 檔案2
on 合併條件1 and 合併條件2

其中inner為合併的方式,另有left、right、full,其合併後會依據宣告做合併的方向
如left join,則是檔案1<檔案2
right join,檔案1>檔案2
full join,則是整體合併,沒合併到也能看到

其結果如下



5.Proc SQL and SAS Macro language

以下需具有巨集語法的經驗方能運用自如:
SQL另有提供將搜尋後的結果納入巨集語法MARCO中
其方式就是使用INTO的方法
語法如下

data king;
input OBS PATIENT DATE date7. PULSE TEMP BPS BPD ;
cards;
1 101 25MAY01 72 98.5 130 88
2 101 01JUN01 75 98.6 133 92
3 101 08JUN01 74 98.5 136 90
4 102 30JUL01 81 99.0 141 93
5 102 06AUG01 77 98.7 144 97
6 102 13AUG01 78 98.7 142 93
7 103 24JUL01 77 98.3 137 79
8 103 31JUL01 77 98.5 133 74
9 103 07AUG01 78 98.6 140 80
10 103 14AUG01 75 99.2 147 89
11 104 22AUG01 72 98.8 128 83
12 104 29AUG01 69 99.1 131 86
13 104 05SEP01 71 98.9 127 82
;
run;



PROC SQL;
SELECT
patient into: p1 separated by ','
FROM king
;
QUIT;

%put &p1 ;


上述語法中,欲將patient變相所抓取的資料放入MARCO語法
故 鍵入 INTO 宣告 並 使用冒號:
並接上巨集變數P1
而在巨集使用時宣告%put &p1(此用法僅為範例,尚有更多巨集用途自行開發)
把抓取的patient值轉為巨集指令 而separated by ','僅是轉換時給予頓號(可加可不加)
但整體來說僅一個字串
"101,101,101,102,102,102,103,103,103,103,104,104,104"變為巨集語言
而此範例可以在log視窗處看到結果
如下





然而上述作法僅有將一個字串轉換為巨集語言
若要將同個變相轉為多個巨集語言時可改為如下

PROC SQL;
SELECT
distinct patient into:p1 - :p4
FROM king
;
QUIT;
%put &p1 &p2 &p3 &p4 ;


上述distinct僅是宣告patient的值有哪幾類予以顯示出

而上述中 :p1 - :p4
則是將patient的值轉為四個巨集語言P1 p2 p3 p4
也可以改寫為 :p1 :p2 :p3 :p4
只是當宣告量一多時則用 - 來概括
其結果如下


當然對於多個變相要做轉換巨集語言除了重複上述動作外,仍可一次寫完
其語法如下

PROC SQL;
SELECT
bps , bpd into: s1- :s10 , :q1-:q10
FROM king
;
QUIT;
%put &s6 &s9 &q3 &q10;


中途僅用逗號做區隔即可
如S1-S10 與 q1-q10 各代表bps與bpd前十個資料
如取 s6 s9 q3 q10
其結果如下




6.Editing Observations
SQL語法允許過程中新增或刪減觀察值

若要新增觀察值時可利用INSERT INTO,並配合VALUES或SET,做新增觀察值的方式
語法如下

data king;
input OBS PATIENT DATE date7. PULSE TEMP BPS BPD ;
cards;
1 101 25MAY01 72 98.5 130 88
2 101 01JUN01 75 98.6 133 92
3 101 08JUN01 74 98.5 136 90
4 102 30JUL01 81 99.0 141 93
5 102 06AUG01 77 98.7 144 97
6 102 13AUG01 78 98.7 142 93
7 103 24JUL01 77 98.3 137 79
8 103 31JUL01 77 98.5 133 74
9 103 07AUG01 78 98.6 140 80
10 103 14AUG01 75 99.2 147 89
11 104 22AUG01 72 98.8 128 83
12 104 29AUG01 69 99.1 131 86
13 104 05SEP01 71 98.9 127 82
;
run;
PROC SQL;
INSERT INTO king
VALUES(14 , 102, '20AUG2001'd , 75, 98.4, 122, 90);
QUIT;

上述語法中 INSERT INTO則是指定要新增的觀察值放入king資料檔中
VALUES則是將新增的觀察值其值依位置次序放入,也就是不管變相為何,在原始資料king中會先放入14再放入102....至122、90去填補各變相位置

結果如下圖



然而對於依位置次序放入有時會有不符合需求,故以SET的方式來表現
語法如下

PROC SQL;
INSERT INTO king
SET PATIENT=106, DATE='27AUG2001'd, PULSE=77, TEMP=98.8, BPS=129, BPD=88 ;
QUIT;


其用法則式以SET宣告,並指定各變相值為如何
其結果如下



若要針對某個觀察值或符合某條件的觀察值予以刪除時可以使用DELETE語法,其語法如下

PROC SQL;
delete from king
WHERE PATIENT = 101;
QUIT;

此DELETE須配合where等條件式,若未使用則觀察值會被刪光光,是不得不注意的
其結果如下



此外對於某個觀察值或符合某條件的觀察值欲以更正或是更新,可利用UPDATE,並以SET與WHERE來配合更改資料,
其語法如下

PROC SQL;
UPDATE king
set BPD=BPD*2
where PATIENT=103;
quit;

上述語法則是更新原始資料king內符合(where)PATIENT=103,則將BPD給予兩倍
其結果如下



7.Data Table Management

SQL語法中有幾種主要語言其中select,另有上述介紹過的INSERT INTO等
而再接下來說明的則是另一種對於資料表格內變相做修飾的方法ALTER TABLE,如同字面上的翻譯就是修改表格
而在使用了ALTER TABLE關鍵字後可以針對資料內的變相做長度變更、型態變更、輸出型態變更、標籤變更或剃除某個變相等,其語法如下

data king;
input OBS PATIENT DATE date7. PULSE TEMP BPS BPD ;
cards;
1 101 25MAY01 72 98.5 130 88
2 101 01JUN01 75 98.6 133 92
3 101 08JUN01 74 98.5 136 90
4 102 30JUL01 81 99.0 141 93
5 102 06AUG01 77 98.7 144 97
6 102 13AUG01 78 98.7 142 93
7 103 24JUL01 77 98.3 137 79
8 103 31JUL01 77 98.5 133 74
9 103 07AUG01 78 98.6 140 80
10 103 14AUG01 75 99.2 147 89
11 104 22AUG01 72 98.8 128 83
12 104 29AUG01 69 99.1 131 86
13 104 05SEP01 71 98.9 127 82
;
run;


PROC SQL ;
ALTER TABLE king
add kkk num
MODIFY DATE FORMAT=MMDDYY8.
DROP TEMP
;

UPDATE king
set kkk=BPD+BPS
;

select * , BPD+BPS as nnn
from king ;
QUIT;


上述語法中
宣告ALTER TABLE來修飾king資料表

add則是宣告新增變項kkk,並且資料型態為數值型(num)[文字型可改char],

MODIFY則是宣告修飾已存在的變項,DATE的格式改為FORMAT=MMDDYY8.

DROP則是宣告拋棄TEMP變項

而上述這些語法可以配合其他用法如ALTER TABLE新增變項再利用UPDATE將新增的變項導入新值

另外新增變項也可以在SELECT部分實現,如上 BPD+BPS as nnn

其結果如下

2008年12月26日 星期五

Easy as Pie Charts

原文出處:http://www2.sas.com/proceedings/forum2008/071-2008.pdf




此文主要是用在圓餅圖的美化
一開始的圓餅圖畫法如下
Example 1
1.2D圓餅圖

goptions device=gif gsfname=chart hpos=100 vpos=100 htext=2
ftext=zapfb ;
data example1 ;
input dessert $3. ;
datalines ;
Pie
;
run ;
proc gchart data=example1 ;
title "Example 1a: Pie Hole Thin" ;
pie dessert / noheading
slice=none value=none ;
footnote "You always win with a Pie Hole Thin!" ;
run ;
quit ;


2.3D圓餅圖

goptions device=gif gsfname=chart hpos=100 vpos=100
htext=2 ftext=zapfb ;
data example1 ;
input dessert $3. ;
datalines ;
Pie
;
run ;
proc gchart data=example1 ;
title "Example 1b: Pie Hole Thick" ;
pie3d dessert / noheading
slice=none value=none ;
footnote "The greatest pick is a Pie Hole Thick! (50% more filling)" ;
run ;
quit ;


3.甜甜圈型圓餅圖

goptions device=gif gsfname=chart hpos=100 vpos=100
htext=2 ftext=zapfb ;
data example1 ;
input dessert $3. ;
datalines ;
Pie
;
run ;
proc gchart data=example1 ;
title "Example 1c: Pie Hole Trim" ;
donut dessert / noheading
slice=none value=none label=("50% less filling")
donutpct=50 ;
footnote "Stay slim with a Pie Hole Trim!" ;
run ;
quit ;


上述三種圓餅圖語法僅差在是否宣告為pie, pie3d, 或是donut.
三種圖如下





不過上述語法仍有一些圖形化的修飾語法,如noheading slice=none value=none ,其中noheading與圖型比例資料類型的子標題有關,如不宣告則圓餅圖上方會出現該圖形的子標題"frequency of dessert";slice為分組變相的標籤位置,可將none改為inside或outsinde;value為計算變項的結果位置,可將none改為inside或是outside.下面則進一步說明如何利用這些宣告來繪製圓餅圖.




Example 2

如下語法為例(以2D圓餅圖作說明)

goptions device=gif gsfname=chart hpos=100 vpos=100
htext=2 ftext=zapfb ;
proc format ;
value example2a 1="$1.99" 2="$2.99" 3="$3.99" 6="$6.99" ;
value example2b 1="$3.99" 2="$5.99" 3="$7.99" 6="$13.99" ;
value example2c 1="$0.99" 2="$1.49" 3="$1.99" 6="$3.49" ;
run ;
data example2 ;
input size $ portion ;
datalines ;
Small 1
Medium 2
Large 3
X-Large 6
;
run ;
proc gchart data=example2 ;
title "Example 2a: Pie Hole Thin Slices" ;
pie size / sumvar=portion noheading
slice=inside value=inside
;
format portion example2a. ;
footnote "Get a whole Pie Hole Thin for just $12.99!" ;
run ;
quit ;



在pie後所宣告的變項size如同proc means使用class的用途,將該變項各類型定義,並且在
sumvar=宣告計算的變項或是比例,也可用freq= ,但兩者仍有不同,一個是值一個是次數

slice=是指size宣告內各分組標籤位置(可改為none,outside,inside, arrow)

value=是指sumvar計算後之值的位置(可改為none,outside,inside)

結果如下圖


而3D 與 甜甜圈圓餅圖 結果與上述相同

goptions device=gif gsfname=chart hpos=100 vpos=100 htext=2 ftext=zapfb ;
proc format ;
value example2a 1="$1.99" 2="$2.99" 3="$3.99" 6="$6.99" ;
value example2b 1="$3.99" 2="$5.99" 3="$7.99" 6="$13.99" ;
value example2c 1="$0.99" 2="$1.49" 3="$1.99" 6="$3.49" ;
run ;
data example2 ;
input size $ portion ;
datalines ;
Small 1
Medium 2
Large 3
X-Large 6
;
run ;
proc gchart data=example2 ;
title "Example 2b: Pie Hole Thick Slices" ;
pie3d size / sumvar=portion noheading slice=inside value=inside ;
format portion example2b. ;
footnote "Get a whole Pie Hole Thick for just $25.99!" ;
run ;
quit ;
proc gchart data=example2 ;
title "Example 2c: Pie Hole Trim Slices" ;
donut size / sumvar=portion noheading slice=inside
value=inside
donutpct=50 ;
format portion example2c. ;
footnote "Get a whole Pie Hole Trim for just $6.49!" ;
run ;
quit ;


甜甜圈圓餅圖中donutpct=50 , 是說明甜甜圈中間那個"洞"的大小




Example 3

接著進一步說明如何將圓餅圖作切分
語法如下

goptions device=gif gsfname=chart hpos=100 vpos=100
htext=2 ftext=zapfb ;
data example3 ;
input flavor & $15. sales ;
datalines ;
Apple 6127
Banana Cream 911
Blueberry 875
Cherry 4592
French Silk 1106
Key Lime 1869
Lemon Meringue 1227
Peach 1322
Pecan 1870
Pumpkin 2991
Rhubarb 1794
Sweet Potato 997
;
run ;
proc gchart data=example3 ;
title "Example 3: Most Frequently Purchased Pies" ;
pie flavor / sumvar=sales noheading slice=inside
value=none percent=inside
fill=solid cfill=STYBR other=5 otherlabel="All Others"
;
footnote "The 'All Others' slice contains pies purchased < 5% of the time" ;
run ;
quit ;


其中的percent=是顯示圓餅圖被切分的百分比並顯示其位置(none, inside, outside)
fill=為選擇圖層填滿之效果(solid, x, empty),一般可以不用宣告
cfill=為圖層填滿之效果,可參考SAS patterns的說明,或是直接打上自己想要的顏色如(red, green, black, cyan),一般可以不用宣告,引用預設值

other=5則是挑選後百分之5作為其他群組,可以自行改為其他百分比
otherlabel="All Others" 則是將挑選出來的增加標籤"All Others"

結果如下圖


若想要把圓餅圖內的顏色作層次,其實可以修改一下語法

在goptions內 加入 colors=(red green .... 等)
或是利用pattern語法宣告顏色

語法如下

goptions device=gif gsfname=chart hpos=100 vpos=100 htext=2
ftext=zapfb colors=(black blue green gray lipk) ;


data example3 ;
input flavor $15. sales ;
datalines ;
Apple 6127
Banana Cream 911
Blueberry 875
Cherry 4592
French Silk 1106
Key Lime 1869
Lemon Meringue 1227
Peach 1322
Pecan 1870
Pumpkin 2991
Rhubarb 1794
Sweet Potato 997
;
run ;


filename chart "C:\My Documents\Graphs\example3.gif" ;

pattern1 color=black;
pattern2 color=blue;
pattern3 color=green;
pattern4 color=gray;
pattern5 color=lipk;
pattern6 color=lime;
pattern7 color=cyan;
pattern8 color=red;

proc gchart data=example3 ;
title "Example 3: Most Frequently Purchased Pies" ;
pie flavor / sumvar=sales noheading slice=inside value=none
percent=inside
other=3 otherlabel="All Others" ;
footnote "The 'All Others' slice contains pies purchased < 5% of the time" ;
run ;
quit ;


其結果如下圖





Example 4
當資料有分組時,以下方式就是將分組之圓餅圖同時顯示

goptions device=gif gsfname=chart hpos=100 vpos=100
htext=2 ftext=zapfb ;
data example4 ;
input season flavor $ sales ;
cards ;
1 a 100
1 b 200
1 c 300
1 d 400
1 e 500
2 a 500
2 b 400
2 c 300
2 d 200
2 e 100
3 a 200
3 b 200
3 c 200
3 d 200
3 e 200
4 a 100
4 b 200
4 c 300
4 d 200
4 e 100
;
run ;
proc gchart data=example4 ;
title "Example 4: Most Frequently Purchased Pies by Season" ;
pie flavor / sumvar=sales noheading slice=inside
value=none percent=inside
fill=solid cfill=STYBR other=5 otherlabel="All Others"
group=season
across=3 down=2
;
footnote "The 'All Others' slice contains pies purchased < 5% of the time" ;
run ;
quit ;


group=是宣告即將分組之變項seasin
across=則是宣告圖堆疊時橫向放幾個組
down=則是宣告圖堆疊時縱向放幾個組
即此結果為2*2的圖形如下





Example 5

若對於圓餅圖想要做出凸顯或隱藏的區塊時如缺角圓餅圖(3D圓餅圖也能直接使用)
以下語法是將某區塊做隱藏


goptions device=gif gsfname=chart hpos=100 vpos=100
htext=2 ftext=zapfb ;
proc format ;
picture example5_ low-high="999 Votes" ;
run ;
data example5 ;
input flavor $15. votes ;
cards;
Blackberry 648
Cranberry 377
Mixed Berry 393
Mud 341
Strawberry 479
Sugar 432
;

proc gchart data=example5 ;
title "Example 5a: The New Customer-Voted Pie is...?" ;
pie flavor / sumvar=votes noheading slice=inside value=outside
percent=outside cfill=Y
ascending angle=10 invisible="Blackberry" ;
format votes example5_. ;
footnote "The new pie will be revealed on Friday at noon!" ;
run ;
quit ;


ascending的宣告是指資料在圖型時的排列
angle=為角度的旋轉
invisible=為想要隱藏的區塊

結果如下圖


然而消失的區塊"Blackberry"若是想要突顯的
則上述語法可以將invisible=替換成
explode=
結果如下圖






Example 6

若想要更進一步排版圓餅圖輸出時
以下語法

goptions device=gif gsfname=chart hpos=100 vpos=100
htext=2 ftext=zapfb ;
data example6 ;
input flavor $15. calories ;
cards;
Apple 255
Banana Cream 505
Blueberry 380
Cherry 450
French Silk 680
Key Lime 365
Lemon Meringue 355
Peach 425
Pecan 625
Pumpkin 280
Rhubarb 375
Sweet Potato 325
;

proc gchart data=example6 ;
title "Example 6: Calories per Slice" ;
pie flavor / sumvar=calories noheading
slice=arrow value=inside ascending
clockwise coutline=BL ;
pattern1 color=CX990000 ;
pattern2 color=CXFFFF99 ;
pattern3 color=CX3333CC ;
pattern4 color=CXCC0000 ;
pattern5 color=CX663300 ;
pattern6 color=CX00CC66 ;
pattern7 color=CXFFFF33 ;
pattern8 color=CXFF9966 ;
pattern9 color=CX996633 ;
pattern10 color=CXFF9900 ;
pattern11 color=CXCC0066 ;
pattern12 color=CXFFCC66 ;
footnote "These numbers are based on a small slice of a Pie Hole Thin" ;
run ;
quit ;


先前有提到slice=是變項資料的標籤位置,
若改為arrow則會拉線出來指示位置

clockwise 是指排列時呈現順時針或逆時針方向

cutline=則是圓餅圖邊框,可打顏色名稱如red , green 等

結果如下圖






Example 7

若對於圓餅圖上的色塊增加圖層說明時(legend),常用GIS的地圖輸出時看到
其方法如下

goptions device=gif gsfname=chart hpos=100 vpos=100
htext=2 ftext=zapfb ;
data example7 ;
input flavor $15. calories ;
cards;
Apple 255
Banana Cream 505
Blueberry 380
Cherry 450
French Silk 680
Key Lime 365
Lemon Meringue 355
Peach 425
Pecan 625
Pumpkin 280
Rhubarb 375
Sweet Potato 325
;
run ;
proc gchart data=example7 ;
title "Example 7: Calories per Slice" ;
pie flavor / sumvar=calories noheading slice=none
value=inside ascending
clockwise coutline=BL legend=legend1 ;

legend1
label=none
position=(left middle)
offset=(2 , 4 )
across=1
shape=bar(4, 4)
cblock=MEGR
cborder=DAGR
cframe=LIGR
order=("Apple" "Pumpkin" "Sweet Potato" "Lemon Meringue"
"Key Lime" "Rhubarb" "Blueberry" "Peach" "Cherry" "Banana
Cream" "Pecan" "French Silk")
;

pattern1 color=CX990000 ;
pattern2 color=CXFFFF99 ;
pattern3 color=CX3333CC ;
pattern4 color=CXCC0000 ;
pattern5 color=CX663300 ;
pattern6 color=CX00CC66 ;
pattern7 color=CXFFFF33 ;
pattern8 color=CXFF9966 ;
pattern9 color=CX996633 ;
pattern10 color=CXFF9900 ;
pattern11 color=CXCC0066 ;
pattern12 color=CXFFCC66 ;
footnote "These numbers are based on a small slice of a Pie Hole Thin" ;
run ;
quit ;



上述中須宣告legend=legend1 的使用
並宣告legend1的特性

label=none 是指說明層加入標題如改為label=("flavor")

position=(left middle)則是排定說明層所在位置
(BOTTOM,MIDDLE,TOP,LEFT,CENTER,RIGHT,OUTSIDE,INSIDE)

offset=(2 , 4 )指說明層偏移距離並可附上位移單位如
offset=(2 pct , 4 pct)

across=1是指說明層內左右納入幾欄資料層

shape=bar(4, 4)是指說明層的色塊說明類型及大小(寬*高)

cblock=MEGR是指說明層邊緣陰影顏色(red, blue 等)
cborder=DAGR是指說明層邊框顏色
cframe=LIGR是指說明層底色
也可以加上CSHADOW=black美化邊框,這些功能有如word內畫圖工具

order=()是指說明層列出變項資料欄的順序
上述這些美化宣告可以任意組合及使用

結果如下圖






Example 8

若有雙層型態時語法如下

goptions device=gif gsfname=chart hpos=100 vpos=100
htext=2 ftext=zapfb ;
data example8 ;
input gender $ style $ orders ;
datalines ;
Male Thin 366
Male Thick 531
Male Trim 103
Female Thin 512
Female Thick 181
Female Trim 307
;
run ;

proc gchart data=example8 ;
title "Example 8: Pie Selection by Gender" ;
pie style / sumvar=orders noheading slice=none
value=outside
percent=outside coutline=BL matchcolor
legend=legend1
detail=gender detail_slice=best detail_value=none
detail_percent=best detail_threshold=0 detail_radius=85 ;


legend1 label=none position=(bottom center)
offset=(0, 4) across=3
shape=bar(4, 2) cblock=MEGR
cborder=DAGR cframe=LIGR ;
pattern1 color=ROSE ;
pattern2 color=OLIVE ;
pattern3 color=LIGB ;
footnote "The first 1000 orders from each gender were counted" ;
run ;
quit ;


matchcolor是指slice的標籤融入背景顏色中
detail=gender是指第二層級的分組
detail_slice=best指第二層級資料標籤(best,none)
detail_value=none第二層級資料(best,none)
detail_percent=best第二層級資料百分比(best,none)
detail_threshold=0第二層級界限百分比(0-75),
如detail_threshold=10,則第一層級低於百分值10會被融入背景中
detail_radius=85第二層圓框面積的縮放百分比(25-90)

結果如下圖



proc gchart

Easy as Pie Charts

2008年12月9日 星期二

利用ODS抓取報表上的結果

一般使用SAS都是先經過proc程序所提供的統計計算去獲得結果並且進一步去轉出該結果的資料。然而當有結果是在報表上的某一個值時,例如利用迴圈的方式想要獲得多組AIC值時,或是參數估計報表內的係數轉換如poisson regression係數轉換為RR值等
如下圖紅框處是我想要擷取的報表


然而很多程序未能支援輸出(output)類似係數估計的報表

固然需要利用其他語法來彌補這樣的問題

如下為人口統計中計算相對危險性所會用到的語法

proc genmod data= deathPoisson;
model _COL10 =class1 class2 class3 class4 class5 / link=log dist=poisson offset=logP lrci;
run;

然而我們僅能在SAS求出Poisson迴歸係數如上圖
但我們會希望能夠求出RR以及信賴區間等資料

可以利用ODS的語法將該係數報表轉換出來,其語法如下


ODS trace on;

proc genmod data= deathPoisson;
model _COL10 =class1 class2 class3 class4 class5 / link=log dist=poisson offset=logP lrci;
run;

ODS trace off;


上述語法中以 ODS trace on; 為開頭, ODS trace off; 為結尾將欲轉出的報表語法包起來
此時先做執行運算動作,並且到log視窗去
會看到如下報表


此為各結果報表的內定值,若對欲特定報表想要轉出時找出該報表對應名稱(Label)

例如欲取出Analysis Of Parameter Estimates這張報表的係數加以換算為RR時在語法中其對應的檔案為ParameterEstimates


找出該張報表的語法後
再把原來的語法改為如下

ods output ParameterEstimates = classparameter;
proc genmod data= deathPoisson;
model _COL10 =class1 class2 class3 class4 class5 / link=log dist=poisson offset=logP lrci;
run;
data CIclass;
set classparameter ;
RR=exp(Estimate);
RRL95=exp(LowerLRCL);
RRU95=exp(UpperLRCL);
proc print data=CIclass;
var Parameter RR RRL95 RRU95;
run;

增加ods output ParameterEstimates = classparameter;宣告即為轉出該結果的係數資料,classparameter則是新取名的檔案名稱
其結果如下圖將轉出的係數再計算其自然數e,即為RR值



2008年6月10日 星期二

Infile

The SAS INFILE and FILE Statements

The SAS INFILE and FILE Statements

原文出處:http://www2.sas.com/proceedings/forum2008/166-2008.pdf


proc report

Learning PROC REPORT by Comparison

Learning PROC REPORT by Comparison

原文出處:
http://www2.sas.com/proceedings/forum2008/170-2008.pdf




此文是以學習proc report並且比較與該程序有相似的程序如proc print, proc tabulate及proc means等



1.與proc print比較
當有資料欲做初步的顯示時通常可利用print的動作將資料秀出,而proc report則也能做相同的動作
如下為proc print的範例(資料來自主程式內的範例,可直接使用)

title 'Simeple Listing' ;
proc print data=sashelp.class ;
var name sex age height weight ;
title2 'PROC PRINT' ;
run ;



結果如下圖

其中的資料各變項僅需在proc print的附屬語法var後面打上欲呈現的變項即可

而在proc report部分語法如下

proc report data=sashelp.class nowd headskip ;
column name sex age height weight ;
define sex / width=3 ;
title2 'PROC REPORT' ; run ;



其中proc report後方的附屬語法:

nowd可以抑制該程序不產生獨立的報告視窗,其效果有如proc print一樣皆將結果輸出在output視窗上,然而獨立的報告視窗有其好處,例如可及時更改該變項顏色或屬性,方便報表輸出的可讀性.

headskip則是修飾報表中變項欄位與第一觀察值的距離

語法中column則與proc print中var效果相同,一樣是宣告欲呈現的變項語法

define則為定義某變項的資料屬性例如後面加上 sex /width=3 ,則宣告sex變項長度為3

根據上述proc report語法,其結果如下,會與proc print輸出報表相似



若常用 proc print功能的人眼尖的話因該會發現print報表其實有個預設值OBS(觀察值序號)
如下圖

而proc print可透過語法將此觀察值序號開啟或關閉,方法如下(只要打上noobs即可關閉)

title 'Simeple Listing' ;
proc print data=sashelp.class noobs ;
var name sex age height weight ;
title2 'PROC PRINT' ;
run ;



然而proc report其實沒有直接提供觀察值序號的功能,
不過可以透過語法的撰寫來達到相似的功能
proc report語法如下

proc report data=sashelp.class nowd headskip ;
column Obs name sex age height weight ;
define sex / width=3 center ;
define age / width=5 ;
define height / format=6.1 ;
define weight / format=6.1 ;
define obs / computed ;
compute obs ;
count+1 ;
obs=count ;
endcomp ;

title2 'PROC REPORT, again' ;
run ;


上述語法中,先在colume後先建立一空變項Obs
接著再宣告Obs格式並利用computed再處理該變項特性值
結果如下圖,會與proc print相似





2.配合sorted listing功能

當資料利用proc print程序列出時,欲先將性別sex變項作排序,其語法如下

proc sort data=sashelp.class out=class ;
by sex ;
run ;
title 'Sorted Listing' ;
proc print data=class ;
var name age ;
by sex ;
id sex ;
title2 'PROC PRINT' ;
run ;

其結果如下



而proc report程序也是能做到上述排序資料的功能,語法如下只要在define後面加個order宣告

proc report data=sashelp.class nowd headskip ;
column sex name age ;
define sex / order width=3 ;
break after sex / skip ;
title2 'PROC REPORT' ;
run ;

其結果如proc print相似如下


而在語法中用到 break after sex / skip ;
則是將報表作斷行的動作,也可將after改為before,
其目的可在後續作資料加總時修改報表板面



3.列出排序後子項的總合
利用proc print加入sumby sex語法,即能表現出sex變項排序後子項目的加總


proc print data=class ;
var name age ;
by sex ;
id sex ;
sumby sex ;
title2 'PROC PRINT' ;
run ;

其結果如下紅框處



而若利用proc report語法呈現如上述的結果報表時,需要有一些宣告

proc report data=sashelp.class nowd ;
column sex name age ;
define sex / order width=3 ;
define age / analysis sum format=4.;
break before sex / skip ;
break after sex / summarize ol ;
rbreak after / summarize dol ;

title2 'PROC REPORT' ;
run ;



其中analysis sum是宣告age變項是可分析可加總

break before sex / skip ;則為依照sex變項作斷行break,斷行的方式為向前(before)斷行並空格(skip),若將skip改為page則斷行會跳頁

break after sex / summarize ol;則是宣告在sex變項斷行後作加總(summarize)的動作並且給予上標單槓符號(ol)----方便報表閱讀

rbreak after / summarize dol ;則是指變項最後斷行的處理(rbreak),將變項做總加總(summarize)的動作,並且給予上標雙槓符號(dol)====

結果如下圖

註:上標符號可改為下標如:ul dul,並且可在獨立視窗時(未宣告nodw時)打上color=顏色(red)

接下來的語法是將上述作一些美化的動作,語法如下

proc report data=sashelp.class nowd ;
column sex sex2 name age ;
define sex / order width=3 noprint ;
define sex2 / computed 'Sex' ;
define age / mean format=best4. ;
break before sex / skip ;
break after sex / summarize ol ;
rbreak after / summarize dol ;
compute sex2 / character length=15 ;
sex2=sex ;
endcomp ;
compute after sex ;
sex2='Average for ' || sex ;
endcomp ;
compute after ;
sex2='Overall Average' ;
endcomp ;

title2 'PROC REPORT and more' ;
run ;


語法中第二行column後多加一個新變項叫做sex2其用意是增加sex的相同變項並給予改名以及後續的應用

在第三行noprint則是將原有的Sex變項作隱藏(可以不打此語法)

在第四行時則定義sex2的變項名稱為"Sex"(有點是說原Sex變項以用來做排序而後面的Sex2則是篡位原來Sex的標題"label")

第九行至第十一行是命名Sex2作為原Sex的標題項目(因為原Sex已被用來做排序了,所以新增Sex2來覆蓋原來的功用)

第十二行至第十四行則為每個sex分類break斷行後的平均值做個標題,其中sex2='Average for ' || sex ;只是說將sex2更名為Average for || sex(F or M ),而||是SAS連結文字用的符號

同理第十五至第十七則是sex2='Overall Average' ;最後為總平均的標題更名為Overall Average

其結果如下圖


接下來則是在把上述的結果報表再次的作修飾的動作


proc format ;
value $gender 'F'='females'
'M'='males' ;
run ;

proc report data=sashelp.class nowd headline ;
column sex name age ;
define sex / order width=3 ;
define age / mean ;
break after sex / skip ;
compute after sex ;
text='Average for ' || strip(put(sex, $gender.)) || ' is ' || put(age.mean, 4.1) ;
line ' ';
line text $40. ;
endcomp ;

compute after ;
line 'Overall Average is ' age.mean 4.1 ;
endcomp ;

title2 'PROC REPORT and more, again' ;
run ;



在第一行至第四行為proc format語法,其用意是宣告gender這個新變項被引用時其值F改為females,M改為males

在第五行時proc report後加上一個宣告headline顧名思義就是加個標頭線

在第八行時定義age做平均(mean)的計算並且呼應後面幾行用到的語法age.mean
若定義為總和sum時後面幾行的語法改為age.sum

第十行至第十三行不同於上一個範例語法的使用,此次則是新增一個類似文字敘述的語法
在第十一行先宣告text文字敘述的特性,其中strip()則為將文字變項前後之間做縮排的動作,也就是將
'Average for '與sex變項與' is '三者之間做縮排(若把strip()取消就可以看出差異點了),而put語法則是導入age.mean資料並且宣告其字元長度(4.1為4個字元長且小數點取1位)
接著第十二行則是新增行並以空白''做為表現,也可改為line '--------------------------';(有點類似自行做圖)
在第十三行則是將剛剛的text文字做使用的動作並且給予字元特徵40個字元長度

第十五行至第十七行與上一個範例類似,在最後做總平均的計算

其結果如下





4.與PROC TABULATE做比較

proc tabulate在SAS中是用來歸納特定變項的基本統計資料,例如平均數、樣本數等

其語法如下


title 'Summary Statistics' ;
proc tabulate data=sashelp.class ;
class sex ;
var age ;
table sex, age*(n*f=4. mean*f=6.2) ;
title2 'PROC TABULATE' ;
run ;


其中 class 指定分層變項,var 為分析變性
proc tabulate程序主要語法為table的宣告
其中先以sex作報表分類再以逗號區隔計算age的樣本數(n)、平均數(mean);而括號內f為宣告格式

結果如下圖


而在proc report語法中可以做出類似的報表
語法如下

proc report data=sashelp.class nowd split='~' box ;
column sex age age=avg_age ;
define sex / group width=3 ;
define age / n 'N' format=4.0 width=4;
define avg_age / mean 'Average~Age' format=6.2 width=7;
title2 'PROC REPORT' ;
run ;


眼尖的話因該就會發現其實只是要proc report程序做點外觀的變化,也就是增加box的宣告
結果如下圖

或者是可以把box改為headline的宣告其結果就如下圖



列聯表的應用
想到列聯表因該就會想到proc freq的使用
proc tabulate則是可以做出類似的輸出
語法如下

options missing='0' ;
title 'Cross-tabulation' ;
proc tabulate data=sashelp.class ;
class sex age ;
table age, sex*n*f=4. ;
title2 'PROC TABULATE' ;
run ;

上述語法只是要求顯示樣本數而已
其結果如下



利用proc report語法也能求出類似報表
語法如下
proc report data=sashelp.class nowd headline ;
column age sex ;
define age / group ;
define sex / across width=3 right ;
title2 'PROC REPORT' ;
run ;

語法across是用來宣告sex變項做交叉表的分類,而因沒有再分析其他變項,則sex變項僅計算其次數(n)

其結果如下圖



若想做較複雜的列聯關係表,如性別與年齡分層後的身高平均
如下為proc tabulate提供的做法

options missing='?';
title 'Cross-tabulation with Summary' ;
proc tabulate data=sashelp.class ;
class sex age ;
var height ;
table age, sex*height*mean*f=6.1 ;
title2 'PROC TABULATE' ;
run ;

如下圖僅是根據age, sex分層將height計算其平均




而proc report的做法也有所相似如下

proc report data=sashelp.class nowd split='~' headline ;
column age sex, height ;
define age / group ;
define sex / across '__Sex__' width=3 right ;
define height / analysis mean 'Average~Height'
format=6.1 width=8 ;

title2 'PROC REPORT' ;
run ;



增加, height 用來宣告sex分類下的顯示
而define height / analysis mean 'Average~Height'
format=6.1 width=8 ;
的宣告計算其結果

其結果如下



若想計算列聯表中樣本數的百分比資料,有如proc freq所計算的百分比
在proc tabulate語法如下

title 'Percentages' ;
proc tabulate data=sashelp.class ;
class sex ;
table sex, n="樣本數" pctn="百分比";
title2 'PROC TABULATE' ;
run ;


僅是在table做一個計算的宣告 pctn 計算Sex變項的百分比

結果如下圖



而利用proc report的方式語法如下

proc report data=sashelp.class nowd box ;
column sex N pctn ;
define sex / group width=3;
define n / width=5 ;
define pctn / '%' format=percent7.1 ;
title2 'PROC REPORT' ;
run ;


結果如下圖





5.與PROC MEANS做比較


最後若想要做出有如proc means程序一樣能夠提供多種基本描述性統計資料
其語法如下

title 'Summary Statistics 2' ;
proc means data=sashelp.class mean std min max maxdec=1;
class sex ;
var height ;
title2 'PROC MEANS' ;
run ;

proc means有本身預設的描述性統計結果的顯示,而上述則欲顯示平均、標準差、最小值及最大值
其結果如下




如利用proc report的語法欲做出如proc means類似報表,其語法如下

proc report data=sashelp.class nowd split='~' headline ;
column sex height, (n mean std min max) ;
define sex / group width=3 ;
define height / '__Height__' ;
define n / 'N' width=3 ;
define mean / 'Mean' format=5.1 ;
define std / 'Std~Dev' format=5.2 ;
define min / 'Min' format=5.1 ;
define max / 'Max' format=5.1 ;

title2 'PROC REPORT' ;
run ;

上述語法是將各描述性統計值須先做宣告的動作
其結果如下